home *** CD-ROM | disk | FTP | other *** search
/ EnigmA Amiga Run 1998 May / EnigmA AMIGA RUN 27 (1998)(G.R. Edizioni)(IT)[!][issue 1998-05].iso / earcd / sinclair-ql / setdate_bas < prev    next >
Text File  |  1998-02-11  |  3KB  |  91 lines
  1. 100 DIM Dat$(20),Mon$(36),M$(3),K$(1)
  2. 110  Dat$=DATE$
  3. 120 Mon$="JanFebMarAprMayJunJulAugSepOctNovDec"
  4. 130 Y%=Dat$(1 TO 4):M$=Dat$(6 TO 8):Mn%=((M$ INSTR Mon$)+2)/3:D%=Dat$(10 TO 11)
  5. 140 H%=Dat$(13 TO 14):M%=Dat$(16 TO 17):S%=Dat$(19 TO 20)
  6. 150 OPEN#4;"Con_512x256a0x0"
  7. 160 PAPER#4;228:INK#4;7:CLS#4
  8. 170 BANNER -1,10,7,4,"SPC:Select  ¼ ¿:Reduce  ½ ¾:Increase"
  9. 180 BANNER -1,50,7,210,"TIME: hh mm ss"
  10. 190 BANNER 190,90,7,210,NUM$(H%,2)
  11. 200 BANNER 238,90,7,210,NUM$(M%,2)
  12. 210 BANNER 286,90,7,210,NUM$(S%,2)
  13. 220 BANNER -1,130,7,210,"DATE: day month year"
  14. 230 BANNER 172,170,7,210,NUM$(D%,2)
  15. 240 BANNER 220,170,7,210,M$
  16. 250 BANNER 280,170,7,210,NUM$(Y%,4)
  17. 260 BANNER -1,210,7,4,"Esc:Abort  ENTER:Set Clock & Quit"
  18. 270 F=0
  19. 280 REPeat Key_Loop%
  20. 290  SELect ON F
  21. 300  =0:BANNER_TXT 190,90,7,255,NUM$(H%,2)
  22. 310  =1:BANNER_TXT 238,90,7,255,NUM$(M%,2)
  23. 320  =2:BANNER_TXT 286,90,7,255,NUM$(S%,2)
  24. 330  =3:BANNER_TXT 172,170,7,255,NUM$(D%,2)
  25. 340  =4:BANNER_TXT 220,170,7,255,M$
  26. 350  =5:BANNER_TXT 280,170,7,255,NUM$(Y%,4)
  27. 360  END SELect 
  28. 370  K$=INKEY$(#4,-1):K=CODE(K$)
  29. 380  SELect ON K
  30. 390  =32,10
  31. 400   SELect ON F
  32. 410   =0:BANNER_TXT 190,90,7,210,NUM$(H%,2)
  33. 420   =1:BANNER_TXT 238,90,7,210,NUM$(M%,2)
  34. 430   =2:BANNER_TXT 286,90,7,210,NUM$(S%,2)
  35. 440   =3:BANNER_TXT 172,170,7,210,NUM$(D%,2)
  36. 450   =4:BANNER_TXT 220,170,7,210,M$
  37. 460   =5:BANNER_TXT 280,170,7,210,NUM$(Y%,4)
  38. 470   END SELect 
  39. 480   IF K=10 THEN 
  40. 490    SDATE Y%,Mn%,D%,H%,M%,S%
  41. 500    EXIT Key_Loop%
  42. 510   END IF 
  43. 520   F=(F+1) MOD 6
  44. 530  =200,208
  45. 540   SELect ON F
  46. 550   =0:H%=(H%+1) MOD 24
  47. 560   =1:M%=(M%+1) MOD 60
  48. 570   =2:S%=(S%+1) MOD 60
  49. 580   =3:D%=(D% MOD 31)+1
  50. 590   =4:Mn%=(Mn% MOD 12)+1:M$=Mon$(Mn%*3-2 TO Mn%*3)
  51. 600   =5:Y%=Y%+1
  52. 610   END SELect 
  53. 620  =192,216
  54. 630   SELect ON F
  55. 640   =0:H%=(H%-1) MOD 24
  56. 650   =1:M%=(M%-1) MOD 60
  57. 660   =2:S%=(S%-1) MOD 60
  58. 670   =3:D%=((D%-2) MOD 31)+1
  59. 680   =4:Mn%=((Mn%-2) MOD 12)+1:M$=Mon$(Mn%*3-2 TO Mn%*3)
  60. 690   =5:Y%=Y%-1
  61. 700   END SELect 
  62. 710  =27:EXIT Key_Loop%
  63. 720  END SELect 
  64. 730 END REPeat Key_Loop%
  65. 740 CLOSE#4
  66. 750 STOP
  67. 760 DEFine PROCedure BANNER(Xx%,Yy%,Ink%,Pap%,F$)
  68. 770  LOCal L%,X%,Y%,W%,H%
  69. 780  L%=LEN(F$):W%=12*(L%+1):H%=30
  70. 790  IF Xx%<0 THEN X%=(512-W%)/2:ELSE X%=Xx%:END IF 
  71. 800  IF Yy%<0 THEN Y%=(256-H%)/2:ELSE Y%=Yy%:END IF 
  72. 810  BLOCK#4;W%,H%,X%+6,Y%+4,0
  73. 820  BLOCK#4;W%,H%,X%,Y%,0
  74. 830  BANNER_TXT Xx%,Yy%,Ink%,Pap%,F$
  75. 840 END DEFine 
  76. 850 DEFine PROCedure BANNER_TXT(Xx%,Yy%,Ink%,Pap%,F$)
  77. 860  LOCal L%,X%,Y%,W%,H%
  78. 870  L%=LEN(F$):W%=12*(L%+1):H%=30
  79. 880  IF Xx%<0 THEN X%=(512-W%)/2:ELSE X%=Xx%:END IF 
  80. 890  IF Yy%<0 THEN Y%=(256-H%)/2:ELSE Y%=Yy%:END IF 
  81. 900  BLOCK#4;W%-4,H%-2,X%+2,Y%+1,Pap%
  82. 910  CSIZE#4;2,1:OVER#4;1:INK#4;0
  83. 920  CURSOR#4;X%+5,Y%+4:PRINT#4;F$;
  84. 930  CURSOR#4;X%+7,Y%+4:PRINT#4;F$;
  85. 940  CURSOR#4;X%+5,Y%+6:PRINT#4;F$;
  86. 950  CURSOR#4;X%+7,Y%+6:PRINT#4;F$;
  87. 960  INK#4;Ink%
  88. 970  CURSOR#4;X%+6,Y%+5:PRINT#4;F$;
  89. 980 END DEFine 
  90. 990 DEFine FuNction NUM$(N%,M%):LOCal N$(32):N$=FILL$("0",M%)&N%:RETurn N$(LEN(N$)-M%+1 TO LEN(N$)):END DEFine 
  91.